raveos-theme/hyprland/theme-data/DankMaterialShell/quickshell/Modules/DankBar/AxisContext.qml


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

import QtQuick

QtObject {
    id: root

    property string edge: "top"

    readonly property string orientation: isVertical ? "vertical" : "horizontal"
    readonly property bool isVertical: edge === "left" || edge === "right"
    readonly property bool isHorizontal: !isVertical

    function primarySize(item) {
        return isVertical ? item.height : item.width
    }

    function crossSize(item) {
        return isVertical ? item.width : item.height
    }

    function setPrimaryPos(item, value) {
        if (isVertical) {
            item.y = value
        } else {
            item.x = value
        }
    }

    function getPrimaryPos(item) {
        return isVertical ? item.y : item.x
    }

    function primaryAnchor(anchors) {
        return isVertical ? anchors.verticalCenter : anchors.horizontalCenter
    }

    function crossAnchor(anchors) {
        return isVertical ? anchors.horizontalCenter : anchors.verticalCenter
    }

    function outerVisualEdge() {
        if (edge === "bottom") return "bottom"
        if (edge === "left") return "right"
        if (edge === "right") return "left"
        if (edge === "top") return "top"
        return "bottom"
    }

    signal axisEdgeChanged()
    signal axisOrientationChanged()
    signal changed()  // Single coalesced signal

    onEdgeChanged: {
        axisEdgeChanged()
        axisOrientationChanged()
        changed()
    }
}