// Config created by Keyitdev https://git.rp1.hu/gabeszm/sddm-rave-theme
// Copyright (C) 2022-2025 Keyitdev
// Based on https://github.com/MarianArlt/sddm-sugar-dark
// Distributed under the GPLv3+ License https://www.gnu.org/licenses/gpl-3.0.html

import QtQuick 2.15
import QtQuick.Controls 2.15

Column {
    id: clock

    width: parent.width
    spacing: root.font.pointSize * 0.45

    Image {
        id: logoImage

        anchors.horizontalCenter: parent.horizontalCenter
        source: (config.Logo && config.Logo !== "") ? Qt.resolvedUrl("../" + config.Logo) : ""
        fillMode: Image.PreserveAspectFit
        width: Math.min(root.font.pointSize * 8.5, root.height * 0.10)
        height: Math.min(root.font.pointSize * 8.5, root.height * 0.10)
        visible: config.Logo && config.Logo !== ""
    }

    Label {
        id:headerTextLabel

        anchors.horizontalCenter: parent.horizontalCenter

        font.pointSize: root.font.pointSize * 1.8
        color: config.HeaderTextColor
        style: Text.Raised
        styleColor: Qt.rgba(0, 0, 0, 0.45)
        renderType: Text.QtRendering
        text: config.HeaderText
    }

    Label {
        id: timeLabel

        anchors.horizontalCenter: parent.horizontalCenter

        font.pointSize: Math.min(root.font.pointSize * 2.4, root.height * 0.040)
        font.bold: true
        color: config.TimeTextColor
        style: Text.Raised
        styleColor: Qt.rgba(0, 0, 0, 0.45)
        renderType: Text.QtRendering

        function updateTime() {
            text = new Date().toLocaleTimeString(Qt.locale(config.Locale), config.HourFormat == "long" ? Locale.LongFormat : config.HourFormat !== "" ? config.HourFormat : Locale.ShortFormat)
        }
    }

    Label {
        id: dateLabel

        anchors.horizontalCenter: parent.horizontalCenter
        
        color: config.DateTextColor
        font.pointSize: root.font.pointSize * 0.82
        font.bold: true
        style: Text.Raised
        styleColor: Qt.rgba(0, 0, 0, 0.45)
        renderType: Text.QtRendering

        function updateTime() {
            text = new Date().toLocaleDateString(Qt.locale(config.Locale), config.DateFormat == "short" ? Locale.ShortFormat : config.DateFormat !== "" ? config.DateFormat : Locale.LongFormat)
        }
    }

    Timer {
        interval: 1000
        repeat: true
        running: true
        onTriggered: {
            dateLabel.updateTime()
            timeLabel.updateTime()
        }
    }

    Component.onCompleted: {
        dateLabel.updateTime()
        timeLabel.updateTime()
    }
}