# Maintainer: RaveOS Team
#
# raveos-hyprland-theme
# ---------------------
# Hyprland DE téma csomag: Lua konfig, DankMaterialShell (DMS) shell, hyprshell
# ablakváltó, kitty, fastfetch, GTK/ikontémák.
#
# Az install script (raveos-hyprland-apply.service) egyszer fut boot-kor és
# bemásolja a theme-data tartalmát /etc/skel-be és minden meglévő user home-jába.
#
# Az SDDM login téma külön csomagban van (raveos-sddm-theme), mert korábban
# mind a négy DE-téma csomag (cosmic/gnome/hyprland/plasma) ugyanazt a
# byte-azonos SDDM temat csomagolta duplán.

pkgname=raveos-hyprland-theme
pkgver=0.0.0
pkgrel=53
pkgdesc="RaveOS Hyprland theme payload and installer (includes DankMaterialShell)"
arch=('any')
url="https://raveos.local"
license=('custom')
conflicts=('raveos-cosmic-theme' 'raveos-gnome-theme')

# Futáshoz szükséges csomagok
depends=(
    'dms-shell-hyprland'  # DankMaterialShell - a fő panel/shell + wallpaper
    'matugen'             # wallpaper-alapú színséma generátor (matugen image ...)
    'socat'               # hyprshell socket kommunikációhoz (keybinds)
    'hyprshell'           # Alt+Tab ablakváltó overlay
    'hyprpolkitagent'     # polkit auth agent (GUI sudo kérések), natívan Hyprland/Wayland-hoz
    'qt6ct'               # Qt6 téma konfiguráció (matugen ezt írja a szín-séma alkalmazásakor)
    'kvantum'             # Qt6 SVG téma-motor (QT_STYLE_OVERRIDE=kvantum ezt igényli)
    'raveos-sddm-theme'   # közös RaveOS SDDM login téma
)

# Opcionális csomagok
optdepends=(
    'fastfetch: terminál üdvözlő (profile.d script indítja)'
    'wl-clipboard: wl-paste (clipboard pipeline)'
    'cliphist: clipboard history store'
    'kitty: alapértelmezett terminál'
)

source=()
sha256sums=()

# Build könyvtárak az src mellé, ne a makepkg alapértelmezettbe
BUILDDIR="${startdir}/build"
PKGDEST="${startdir}/build"
SRCDEST="${startdir}/build"
SRCPKGDEST="${startdir}/build"
LOGDEST="${startdir}/build"

package() {
    # theme-data payload: hypr konfig, DMS config, kitty, fastfetch, GTK, stb.
    install -dm755 "${pkgdir}/usr/share/raveos/hyprland-theme"
    cp -r --no-preserve=ownership "${startdir}/theme-data" \
        "${pkgdir}/usr/share/raveos/hyprland-theme/"

    # SDDM téma: külön csomagban (raveos-sddm-theme), lásd depends

    # apply script: boot-kor futó installer (systemd service hívja)
    install -Dm755 "${startdir}/raveos-hyprland-apply.sh" \
        "${pkgdir}/usr/lib/raveos-hyprland-theme/auto-apply.sh"

    # systemd system service: egyszer fut (ConditionPathExists=!.applied guard)
    install -Dm644 "${startdir}/raveos-hyprland-theme-apply.service" \
        "${pkgdir}/usr/lib/systemd/system/raveos-hyprland-theme-apply.service"

    # session init script: első login-kor beállítja a háttérképet a DMS-ben
    install -Dm755 "${startdir}/raveos-session-init.sh" \
        "${pkgdir}/etc/profile.d/raveos-session-init.sh"
}