# Maintainer: nippy <nippy@tuta.io>

pkgname=raveos-center
pkgver=1.0.0
pkgrel=1
pkgdesc="RaveOS Center: apps, updates, drivers, gaming, snapshots and feedback in one place"
arch=('any')
url="https://git.rp1.hu/RaveOS/RaveOS-PKGBUILD"
license=('GPL-3.0-or-later')
depends=('python' 'python-pyqt6' 'polkit' 'pacman' 'pacman-contrib' 'pciutils' 'util-linux')
optdepends=(
    'yay: AUR csomagok'
    'flatpak: Flatpak alkalmazások'
    'snapper: snapshotok btrfs-en'
    'snap-pac: automatikus snapshot csomagműveletek előtt'
    'btrfs-progs: snapshotok btrfs-en'
    'reflector: tükörlista frissítése'
    'scx-scheds: sched_ext ütemezők'
    'gamemode: Gaming mód'
    'mangohud: Gaming mód'
    'sbsigntools: Secure Boot aláírás'
    'efitools: Secure Boot kulcs telepítés'
    'zstd: Secure Boot modul-aláírás'
)
provides=('raveos-app-installer')
conflicts=('raveos-app-installer')
replaces=('raveos-app-installer')
source=()
sha256sums=()

BUILDDIR="${startdir}/build"
PKGDEST="${startdir}/build"
SRCDEST="${startdir}/build"
SRCPKGDEST="${startdir}/build"
LOGDEST="${startdir}/build"

package() {
    local lib="${pkgdir}/usr/lib/raveos-center"

    install -Dm755 "${startdir}/raveos-center" "${pkgdir}/usr/bin/raveos-center"
    install -Dm644 "${startdir}/raveos-center.desktop" "${pkgdir}/usr/share/applications/raveos-center.desktop"
    install -Dm644 "${startdir}/raveos_center/adat/logo.png" "${pkgdir}/usr/share/icons/hicolor/256x256/apps/raveos-center.png"

    install -d -m 755 "${lib}"
    cp -r --no-preserve=ownership "${startdir}/raveos_center" "${startdir}/adat" "${lib}/"
    install -Dm755 "${startdir}/helper/raveos-center-helper" "${lib}/raveos-center-helper"
    install -Dm755 "${startdir}/driverek/raveos-gpu-drivers" "${lib}/raveos-gpu-drivers"
    install -Dm644 "${startdir}/helper/hu.rp1.raveos-center.policy" \
        "${pkgdir}/usr/share/polkit-1/actions/hu.rp1.raveos-center.policy"

    install -Dm755 "${startdir}/secureboot/raveos-secureboot-setup" "${pkgdir}/usr/bin/raveos-secureboot-setup"
    install -d -m 755 "${pkgdir}/usr/share/raveos"
    cp -r --no-preserve=ownership "${startdir}/secureboot/adat" "${pkgdir}/usr/share/raveos/secureboot"

    find "${pkgdir}" \( -name __pycache__ -o -name .DS_Store -o -name '._*' \) -prune -exec rm -rf {} +
    find "${lib}/raveos_center" "${lib}/adat" "${pkgdir}/usr/share/raveos/secureboot" -type d -exec chmod 755 {} +
    find "${lib}/raveos_center" "${lib}/adat" "${pkgdir}/usr/share/raveos/secureboot" -type f -exec chmod 644 {} +
    chmod 755 "${lib}/adat/actions/"*.sh "${pkgdir}/usr/share/raveos/secureboot/installed/"*.sh

    python -m compileall -q -d /usr/lib/raveos-center/raveos_center "${lib}/raveos_center"
}