import io.calamares.ui 1.0
import io.calamares.core 1.0

import QtQuick 2.15
import QtQuick.Layouts 1.15
import "RaveOS"

Rectangle {
    id: oldalsav
    color: Stilus.felulet
    anchors.fill: parent

    Rectangle {
        anchors.top: parent.top
        anchors.bottom: parent.bottom
        anchors.right: parent.right
        width: 1
        color: Stilus.keret
    }

    ColumnLayout {
        anchors.fill: parent
        anchors.topMargin: 28
        anchors.bottomMargin: 28
        anchors.leftMargin: 16
        anchors.rightMargin: 16
        spacing: 28

        RowLayout {
            Layout.leftMargin: 8
            spacing: 12

            Image {
                Layout.preferredWidth: 42
                Layout.preferredHeight: 39
                source: "file://" + Branding.imagePath(Branding.ProductLogo)
                sourceSize.width: 84
                sourceSize.height: 78
                fillMode: Image.PreserveAspectFit
                smooth: true
            }

            ColumnLayout {
                spacing: 2

                Text {
                    text: "RAVEOS"
                    color: Stilus.szoveg
                    font.family: Stilus.cim
                    font.weight: Font.Bold
                    font.pixelSize: 22
                    font.letterSpacing: 1
                }

                Text {
                    text: qsTr("INSTALLER")
                    color: Stilus.szovegHalvany
                    font.family: Stilus.mono
                    font.pixelSize: 11
                    font.letterSpacing: 2
                }
            }
        }

        ColumnLayout {
            Layout.fillWidth: true
            spacing: 2

            Repeater {
                model: ViewManager

                Rectangle {
                    readonly property bool aktualis: index === ViewManager.currentStepIndex
                    readonly property bool megtett: index < ViewManager.currentStepIndex

                    visible: index > 0
                    Layout.fillWidth: true
                    Layout.preferredHeight: 40
                    color: aktualis ? Stilus.aktiv : "transparent"

                    RowLayout {
                        anchors.fill: parent
                        anchors.leftMargin: 12
                        anchors.rightMargin: 12
                        spacing: 12

                        Text {
                            text: (index < 10 ? "0" : "") + index
                            color: aktualis || megtett ? Stilus.zold : Stilus.szovegHalvany
                            font.family: Stilus.mono
                            font.pixelSize: 12
                        }

                        Text {
                            Layout.fillWidth: true
                            text: display
                            elide: Text.ElideRight
                            color: aktualis ? Stilus.szoveg : (megtett ? Stilus.szovegMasodlagos : Stilus.szovegHalvany)
                            font.family: Stilus.font
                            font.pixelSize: 14
                            font.weight: aktualis ? Font.DemiBold : Font.Medium
                        }
                    }
                }
            }
        }

        Item {
            Layout.fillHeight: true
        }

        Text {
            Layout.leftMargin: 12
            text: ("RaveOS " + Branding.string(Branding.Version)).trim()
            color: Stilus.szovegHalvany
            font.family: Stilus.mono
            font.pixelSize: 11
        }
    }
}