# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Contributor: ThatOneCalculator <kainoa@t1c.dev>
# Contributor: Brenno Lemos <brenno@syndel.is>
# Contributor: Gabriel Fox <inbox@gabrielfox.dev>

pkgname=(hyprland hyprpm)
pkgver=0.56.2
pkgrel=10
pkgdesc='a highly customizable dynamic tiling Wayland compositor'
arch=(x86_64 aarch64)
url="https://github.com/hyprwm/${pkgname^}"
license=(BSD-3-Clause)
depends=(cairo # libcairo.so
         aquamarine libaquamarine.so
         libgcc # libgcc_s.so
         'libstdc++' # libstdc++.so
         glibc # libc.so libm.so
         glib2 libgio-2.0.so libgobject-2.0.so
         glslang # libglslang-default-resource-limits.so libglslang.so
         hyprcursor libhyprcursor.so
         hyprgraphics libhyprgraphics.so
         hyprland-guiutils
         hyprlang libhyprlang.so
         hyprutils libhyprutils.so
         hyprwire libhyprwire.so
         lcms2 liblcms2.so
         libdrm # libdrm.so
         libglvnd libEGL.so libGLESv2.so
         libinput # libinput.so
         libx11
         libxcb # libxcb-dri3.so libxcb-present.so libxcb-render.so libxcb-res.so libxcb-shm.so libxcb.so libxcb-xfixes.so libxcb-xinput.so
         libxcomposite # libxcb-composite.so
         libxcursor # libXcursor.so
         libxfixes
         libxkbcommon libxkbcommon.so
         libxrender
         lua # liblua.so
         mesa # libgbm.so
         muparser # libmuparser.so
         opengl-driver
         pango libpango-1.0.so libpangocairo-1.0.so
         pixman libpixman-1.so
         re2 libre2.so
         tomlplusplus libtomlplusplus.so
         util-linux-libs libuuid.so
         wayland libwayland-server.so
         wayland-protocols
         xcb-proto
         xcb-util
         xcb-util-errors # libxcb-errors.so
         xcb-util-image
         xcb-util-keysyms
         xcb-util-renderutil # libxcb-render-util.so 
         xcb-util-wm # libxcb-ewmh.so  libxcb-icccm.so 
         xorg-xwayland)
makedepends=(cmake
             glaze
             hyprland-protocols
             hyprwayland-scanner
             meson
             ninja
             xorgproto)
optdepends=('hyprpm: build and install plugins'
            'hyprshutdown: clean logout and shutdown helper'
            'xdg-desktop-portal-hyprland: xdg-desktop-portal backend for hyprland')
provides=(wayland-compositor)
_archive="${pkgname^}-$pkgver"
source=("$_archive.tar.gz::$url/releases/download/v$pkgver/source-v$pkgver.tar.gz")
sha256sums=('03ad3f5ef152ff44116ffd56fcf808486211ecabf4f0ba567108ee746ba5cd2e')

prepare() {
	ln -sf hyprland-source "$_archive"
	cd "$_archive"
	sed -i -e '/^release:/{n;s/-D/-DCMAKE_SKIP_RPATH=ON -D/}' Makefile
	sed -i -e '/find_package.glaze/s/7...<8 //' {.,hyprpm,start}/CMakeLists.txt
}

build() {
	cd "$_archive"
	make release PREFIX=/usr
}

package_hyprland() {
	cd "$_archive"
	make DESTDIR="$pkgdir" install
	rm -fv "$pkgdir/usr/include/hyprland/src/version.h.in"
	find $pkgdir -name '*hyprpm*' -delete
	install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
}

package_hyprpm() {
	pkgdesc='Plugin manager for Hyprland'
	depends=(cmake
	         cpio
	         glaze
	         hyprland
	         hyprland-protocols
	         hyprwayland-scanner
	         meson)
	cd "$_archive"
	make DESTDIR="$pkgdir" install
	find $pkgdir -type f,l -not -name '*hyprpm*' -delete
	find $pkgdir -type d -empty -delete
	install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
}